Flex 2 컴퍼넌트의 작성과 확장 > ActionScript 컴퍼넌트의 작성 > ActionScript 에 의한 확장된 비주얼 컴퍼넌트의 작성 > 컴퍼넌트의 구현 > commitProperties() 메소드의 구현

commitProperties() 메소드의 구현

컴퍼넌트의 properties 에 대한 변경을 조정하려면 ,commitProperties() 메소드를 사용합니다. 대부분의 경우, 화면상의 컴퍼넌트의 표시 방법으로 영향을 주는 properties 와 함께 사용합니다.

Flex 는,invalidateProperties() 메소드의 호출이 발생했을 때에,commitProperties() 메소드의 호출을 스케줄링 합니다. commitProperties() 메소드는,invalidateProperties() 메소드의 호출 후, 다음번의 render 이벤트의 기간에 실행됩니다. addChild() 메소드를 사용해 컴퍼넌트를 컨테이너에 추가하는 경우,Flex 는,invalidateProperties() 메소드를 자동적으로 호출합니다.

commitProperties() 메소드의 호출은,measure() 메소드의 호출전에 발생합니다. 따라서,measure() 메소드가 사용하는 properties 의 값을 설정할 수 있습니다.

컴퍼넌트의 properties 를 정의하기 위해서 사용하는 전형적인 패턴으로서는, 다음의 예의 같게, getter/setter 메소드를 사용해 properties 를 정의합니다. 

// alignText  properties 용의  private  변수를 정의한다
private var _alignText:String = "right";

// _alignText  properties 의 변화를 나타내는 플래그를 정의한다
private var bAlignTextChanged:Boolean = false;

//  properties 의 getter/setter 메소드를 정의한다        
public function get alignText() :String {
        return _alignText;
}

public function set alignText(t:String) :void {
    _alignText = t;
    bAlignTextChanged = true;

    // 필요에 따라서, commitProperties(), measure(), updateDisplayList()
// 메소드를 trigger  한다 
    // 이 경우, 컴퍼넌트를 재측정할 필요는 없다 
    invalidateProperties();
    invalidateDisplayList();
}

// commitProperties() 메소드를 구현한다 
override protected function commitProperties() :void {
    super.commitProperties();
    
    // 플래그가 alignText  properties 의 변경을 나타내고 있는지 확인한다 
    if (bAlignTextChanged) {
        // 플래그를 리셋트 한다
        bAlignTextChanged = false;

        // 정렬의 변경을 처리한다
    }
}

이 예로 보도록(듯이), setter 메소드는, properties 를 변경해,invalidateProperties() 메소드와 invalidateDisplayList() 메소드를 호출해 돌아옵니다. setter 자체는, 새로운 properties 치를 사용한 계산은 하지 않습니다. 이 설계에 의해, setter 메소드로부터는 곧바로 돌아와, 새로운 값의 처리는 commitProperties() 메소드로 행해지게 됩니다.

컨트롤내의 텍스트의 정렬을 변경해도, 컨트롤의 크기는 반드시 바뀌는 것은 아닙니다. 크기가 바뀌는 경우는,invalidateSize() 메소드를 호출해 measure() 메소드를 trigger 해 주세요.

commitProperties() 메소드를 사용하는 주된 이점은, 다음과 같습니다.

다음의 예에서는,commitProperties() 메소드로, 2 개의 관련하는 properties 를 처리하는 방법을 나타냅니다. 

// text  properties 용의  private  변수를 정의한다
private var _text:String = "ModalText";
private var bTextChanged:Boolean = false;
        
// getter 메소드를 정의한다 
public function get text() :String {
        return _text;
}

// setter 메소드를 정의해,  properties 의 변경시에 invalidateProperties()를
// 호출한다 
public function set text(t:String) :void {
    _text = t;
    bTextChanged = true;
    invalidateProperties();
    // 텍스트가 변경되면, 컨트롤이 디폴트 크기를 재계산한다
    invalidateSize();
    invalidateDisplayList();
}

// alignText  properties 용의  private  변수를 정의한다
private var _alignText:String = "right";
private var bAlignTextChanged:Boolean = false;
        
public function get alignText() :String {
        return _alignText;
}
    
public function set alignText(t:String) :void {
    _alignText = t;
    bAlignTextChanged = true;
    invalidateProperties();
    invalidateDisplayList();
}
    
// commitProperties() 메소드를 구현한다 
override protected function commitProperties() :void {
    super.commitProperties();

    // 플래그가 양쪽 모두의  properties 에 대한 변경을 나타내고 있는지 확인한다 
    if (bTextChanged && bAlignTextChanged) {
        // 플래그를 리셋트 한다
        bTextChanged = false;
        bAlignTextChanged = false;

        // 양쪽 모두의  properties 가 변경되고 있는 경우의 처리를 한다
    }
    
    // 플래그가 text  properties 의 변경을 나타내고 있는지 확인한다 
    if (bTextChanged) {
        // 플래그를 리셋트 한다
        bTextChanged = false;

        // 텍스트의 변경을 처리한다
    }

    // 플래그가 alignText  properties 의 변경을 나타내고 있는지 확인한다 
    if (bAlignTextChanged) {
        // 플래그를 리셋트 한다
        bAlignTextChanged = false;

        // 정렬의 변경을 처리한다
    }
}